// traumatized.txt
//
// Modified basicnpc.txt, where npcs have a random chance of just
// breaking into tears, triggering an alternate node. When a breakdown is 
// triggered, a flag specified by the memory cells is set to 2. It takes 
// two runs through the INIT_STATE to return the character to normal.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Threshold value for the npc being able to talk. On a scale
//     of 1 to 20, get_ran() results above or equal to this value will 
//     result in a normal conversation. Otherwise, the conversation is 
//     diverted to the node in Cell 5.
//   Cell 5 - Alternate node of dialogue for when npc breaks down.
//   Cell 6,7 - Stuff done flag. If both 0, nothing. Otherwise, when the 
//     get_ran() call results in a breakdown, this flag is set to two.
//     When the flag is set to one or two, the conversation defaults to the
//     breakdown. Each time INIT_STATE is called, the flag is reduced
//     by one.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	
	if((get_memory_cell(6) != 0) || (get_memory_cell(7) != 0)) {
		
		if(get_flag(get_memory_cell(6),get_memory_cell(7)) != 0)
			inc_flag(get_memory_cell(6),get_memory_cell(7),-1);

		}

break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE;

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}

	// If I have a shell-shocked flag
	if((get_memory_cell(6) != 0) && (get_memory_cell(7) != 0)) {
		
		// If my shell-shocked flag was set to one, and the party 
		// tries to talk to me again, trigger the alternate node 
		// again.
		if(get_flag(get_memory_cell(6),get_memory_cell(7)) != 0) {
			begin_talk_mode(get_memory_cell(5));
			}
		
		// If I'm shell-shocked and unable to converse normally,
		// trigger my alternate dialogue node and set the flag.
		else if (get_ran(1,1,20) < get_memory_cell(4))  {
			set_flag(get_memory_cell(6),get_memory_cell(7),2);
			begin_talk_mode(get_memory_cell(5));
			}

		// Otherwise, I talk normally.
		else
			begin_talk_mode(get_memory_cell(3));
		}

	// If I don't have a shell-shocked flag.
	else {
		// If I'm shell-shocked and unable to converse normally,
		// trigger my alternate dialogue node.
		if (get_ran(1,1,20) < get_memory_cell(4))  
			begin_talk_mode(get_memory_cell(5));

		// Otherwise, I talk normally.
		else
			begin_talk_mode(get_memory_cell(3));
		}

break;